Плата контролера з безпровідною передачею даних. Має на борту модуль WIFI ESP8266 з антеною.

Флеш пам'яті 4 МБ

Програмується без окремих програматорів прямо через USB-шнурок.

Можна програмувати за допомогою Arduino IDE ESP8266 - в цій статті описано, як налаштувати для цього комп'ютер.

Після налаштування Arduino IDE необхідно вибрати плату NodeMCU 0.9 та відповідний COM-порт. Після цього можна завантажувати програму,наприклад наступну, яка представляє з себе реалізацію простішого веб-сервера (у вас повинна бути налаштована мережа WiFi за допомогою роутера, точки доступу...):

#include <ESP8266WiFi.h>

#include <WiFiClient.h>

#include <ESP8266WebServer.h>

#include <ESP8266mDNS.h>

const char* ssid = "Им'я мережі Вайфай";

const char* password = "пароль мережі Вайфай";

ESP8266WebServer server(80);

const int led = 13;

void handleRoot() {

  digitalWrite(led, 1);

  server.send(200, "text/plain", "Привіт вам від esp8266!");

  digitalWrite(led, 0);

}

void handleNotFound(){

  digitalWrite(led, 1);

  String message = "File Not Found\n\n";

  message += "URI: ";

  message += server.uri();

  message += "\nMethod: ";

  message += (server.method() == HTTP_GET)?"GET":"POST";

  message += "\nArguments: ";

  message += server.args();

  message += "\n";

  for (uint8_t i=0; i<server.args(); i++){

    message += " " + server.argName(i) + ": " + server.arg(i) + "\n";

  }

  server.send(404, "text/plain", message);

  digitalWrite(led, 0);

}

void setup(void){

  pinMode(led, OUTPUT);

  digitalWrite(led, 0);

  Serial.begin(115200);

  WiFi.begin(ssid, password);

  Serial.println("");

  // очікуємо з'єднання

  while (WiFi.status() != WL_CONNECTED) {

    delay(500);

    Serial.print(".");

  }

  Serial.println("");

  Serial.print("Підключено до ");

  Serial.println(ssid);

  Serial.print("IP адрес: ");

  Serial.println(WiFi.localIP());

  if (MDNS.begin("esp8266")) {

    Serial.println("MDNS responder started");

  }

  server.on("/", handleRoot);

  server.on("/inline", [](){

    server.send(200, "text/plain", "все працює як треба");

  });

  server.onNotFound(handleNotFound);

  server.begin();

  Serial.println("HTTP server started");

}

void loop(void){

  server.handleClient();

}

Завантажте цю програму в контролер. Запустіть монітор порту з Arduino IDE та задайте йому швидкість з'єднання 115200. Якщо все правильно налаштовано, в моніторі порту повинна відобразитися IP - адреса контролера. Тепер введіть цю адресу в адресному рядку інтернет-браузера комп'ютера та ви повинні побачити відповідь плати контролера "Привіт вам від esp8266!".