Працюємо з 09:00 до 19:00 без вихідних
Київ біля ТЦ Квадрат бул.Перова

Як задати статичну IP адресу контролеру ESP8266?

Розглянемо це питання на прикладі плати контролера NodeMcu 0.9 ESP-12 WIFI ESP8266.

Вивчаючи стандартні приклади скетчів, які додаються до бібліотек ESP8266WiFi при налаштуванні Arduino IDE для роботи з WiFi контролером ESP8266, усі зупиняються на питанні: "а як же мені дізнатись про IP-адресу, яка в усіх прикладах отримується динамічно, без використання монітору порта?"

Максимум зручностей для виявлення нашого контролера, які пропонуються в прикладах - це пропозиція використовувати технологію mDNS. Це типу локальний спосіб призначення пристроям в мережі своїх символьних імен для доступу до них за протоколом http на tcp.

Перший спосіб - технологія mDNS

Давайте для начала рассмотрим этот способ удобного обращения к нашему WiFi контроллеру при помощи придуманных символьных адресов. Тем более, что в примерах приведен не полный и неправильный синтаксис обращения к классу mDNS.

Действительно, задумка очень интересная. Работает это так: мы в программном коде своей программы указываем символьное название сервера, который будет крутиться в ESP8266. Например мы назовем его "teplica1" (теплица1). И чтобы обратиться к web-странице этого сервера, мы просто в адресной строке браузера нашего компьютера или гаджета пишем

http://teplica1.local/

и браузер нам отобразит содержимое, полученное от контроллера, не зависимо от динамически полученного IP-адреса в данный момент.

Вот изменённый код web-сервера, взятый со стандартного библиотечного примера, который поддерживает сетевое назначение имен mDNS.

#include <ESP8266WiFi.h>
#include <WiFiClient.h>
#include <ESP8266WebServer.h>
#include <ESP8266mDNS.h> //подгружаем библиотеку mDNS
const char* ssid = "****";
const char* password = "******";
ESP8266WebServer server(80);
MDNSResponder mdns; //назначаем экземпляр класса ESP8266mDNS
const int led = 13;
void handleRoot() {
  digitalWrite(led, 1);
  server.send(200, "text/plain", "hello from esp8266!");
  digitalWrite(led, 0);
}
void setup(void){
  pinMode(led, OUTPUT);
  digitalWrite(led, 0);
  Serial.begin(115200);
  WiFi.begin(ssid, password);
  Serial.println("");
  // ожидание соединения
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.print("Connected to ");
  Serial.println(ssid);
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());
  //назначаем символьное имя mDNS нашему серверу опираясь на его динамически полученный IP
 if (MDNS.begin("esp8266", WiFi.localIP())) {
    Serial.println("MDNS responder started");
  }
  server.on("/", handleRoot);
  server.begin();
  Serial.println("HTTP server started"); //активируем сервис MDNS
  MDNS.addService("http", "tcp", 80);
}
void loop(void){
  server.handleClient();
}

Вобщем к обычному коду сервера добавляются всего 4 строки обращения к классу MDNS. К позитиву так же можно отнести и то, что библиотека забирает не очень много памяти контроллера, при её подключении.
Теперь, чтобы обратиться к серверу нам не обязательно знать его IP. Просто достаточно ввести в строку браузера http://esp8266.local/ и получим доступ к веб-страничке контроллера и получим ответ "hello from esp8266!". Красота и великолепие не правда ли!?
Но теперь вернемся к реальности. Технология MDNS на данный момент по умолчанию поддерживается только гаджетами с операционками фирмы Apple. На гаджеты иных операционных систем необходимо устанавливать специальные утилиты, с андроидом вообще плачевнее всего. Вобщем мне такое не подходит, честно говоря.

Хочу статический IP на ESP8266

Раз предыдущий способ не годится для использования на различных гаджетах, давайте разкопаем припрятанные функции библиотеки ESP8266WiFi. Представляю вам функцию, зашитую в стандартную библиотеку, для назначения параметров сетевого соединения контроллера. Её синтаксис выглядит следующим образом.

config (ip, gateway, subnet)

Эта функция принимает следующие параметры: IP-адрес, гейтвей и маску подсети. У них довольно интересный тип переменной (посмотрим в примере). config активируют после функции begin.

Я взял предыдущий пример с mDNS и переделал его под задаваемый IP адрес без класса mDNS.

#include <ESP8266WiFi.h>
#include <WiFiClient.h>
#include <ESP8266WebServer.h>
const char* ssid = "*****";
const char* password = "*****";
IPAddress ip(192,168,1,17);  //статический IP
IPAddress gateway(192,168,1,1);
IPAddress subnet(255,255,255,0);
ESP8266WebServer server(80);
const int led = 13;
void handleRoot() {
  digitalWrite(led, 1);
  server.send(200, "text/plain", "hello from esp8266!");
  digitalWrite(led, 0);
}
void setup(void){
  pinMode(led, OUTPUT);
  digitalWrite(led, 0);
  Serial.begin(115200);
  WiFi.begin(ssid, password);
  WiFi.config(ip, gateway, subnet);
  Serial.println("");
  // ожидание соединения
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.print("Connected to ");
  Serial.println(ssid);
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());
  server.on("/", handleRoot);
  server.begin();
  Serial.println("HTTP server started");
}
void loop(void){
  server.handleClient();
}

После загрузки этой программы в плату контроллера, можно любым браузером в WiFi сети перейти по адресу

http://192.168.1.17

и получим ответ hello from esp8266!

Тоесть мы получаем контроллер, строго привязанный к осязаемому IP адресу. Это дает нам рычаги для организации более сложных конфигураций сети умного дома. Можно работать над организацией клиент-серверных обменов полезной информацией между контроллерами.

Ну что же, продолжим и дальше разкапывать запрятанные возможности нашей родной WiFi библиотеки и отображать результаты разкопок в статьях!

Написати відгук

Примітка: HTML размітка не підтримується! Використовуйте звичайтий текст.
    Погано           Добре
Вимикач круглий 16мм

Вимикач круглий 16мм

Круглий вимикач живленняКолір чорнийЗовнішній діаметр 16 ммУстановочний діаметр 15 ммРозміри вказані..

10.04грн.

Перемикач MTS-102

Перемикач MTS-102

Переключатель на два положения с тремя контактами6А  - 125В AC 3А - 250В ACРазмеры указаны..

15.17грн.

Компаратор подвійний LM393DR

Компаратор подвійний LM393DR

LM393DR в корпусі SOP-8 для поверхневого монтажу.Ці мікросхеми розробники усіляких датчиків для люби..

2.62грн.

Світлодіод ультраяскравий 5мм

Світлодіод ультраяскравий 5мм

Над-яскравий світлодіод діаметром 5 ммКорпус прозорий в світлодіодів різного кольору світіння. Тобто..

1.55грн.

Датчик рівня дискретний горизонтальний

Датчик рівня дискретний горизонтальний

Дискретний датчик, що спрацьовує при досягненні рідиною певного рівня та вище його. В спрацьованому ..

56.33грн.